gen firstname="paul"

gen initial="abcdefghij"

To create a string variable, use the gen command. Enclose the values themselves in double quotes.

replace firstname="bob" if employed==4

replace firstname="sue" if mugged != 3

replace firstname="none" if firstname==""

Not everyone's first name is Paul, so we will need to change the values for some observations. The "if" clause allows us to do this. In the first example only those observations whose values for the variables "employed" is 4 will be changed, all other observations will not be changed. Note the double "=".

The second example will change all observations whose values for mugged are NOT 3.

Finally, we can even change values of a variable based on itself - in this case, we change all the missing names to "none." Note the double equal sign in the if clause!

gen numvar1=1

gen numvar2=numvar1+income

gen numvar3=(numvar1/income)*100

Just like with string variables, you can create new numeric variables with the gen command. Any valid mathematical expression is allowed.

replace numvar1=5 if mugged==3

replace numvar2=income/rand if numvar3>.05

replace numvar2=income/rand if numvar3>.05 & numvar3 != .

replace numvar2=. if citynum==2 | citynum==5 | citynum==7

replace numvar2=. if inlist(citynum,2,5,7)

Replacing values in numeric variables works much the same way as for string variables.

We can use "if" clauses in replacing numeric values as well.

One caveat that often comes up is how Stata treats missing values. Since missing values are equal to positive infinity, the expression "numvar3>5" will include missing values. This may not be what you really want, so you must include the "& numvar3!=." to exclude any missing values.

This will make numvar “missing” if citynum is equal to 2, 5 or 7

A very useful function is “inlist” which allows you to simply list the values you want to match.

recode mugged 1=2

recode mugged 1=2 3=4

recode mugged 1=2 *=5

recode mugged 1 2 3 4=5

recode mugged 1 2 3 4=5, gen(mugged2)

The recode command can be an easy way of changing the values of a numeric variable (recode only works with numeric variables). All you need to do is just provide a list of the values you want to change.
The "*" means all other values not explicitly listed - including missing!
Finally, the "gen()" option tells Stata to create a new variable that will be the recoded version of the original. This is highly reccommended so that you do not destroy your original variable!

This is one way of collapsing values.

gen income_dummy=.

replace income_dummy=1 if income>=6000

replace income_dummy=0 if income<6000

tab mugged, gen(mugged_dummy)

Dummy variables are numeric variables whose values are 0 and 1.  There are two basic ways of creating dummy variables, one is for when you are creating dummies for a continuous variable,

and one for a categorical variable.

egen age_cat = cut(age), at(10,15,20,25,30,35)

egen age_cat = cut(age), group(6)

"cut" is very useful for collapsing variables. You can either specify the lowest value for each new group with the "at()" option. Any observations with a value less than 10 will be given a missing value for age_cat, and all observations with a value greater than 35 will be placed in the "35" age_cat group. or simply specify the number of groups you want with "group()".

egen age_mean = mean(age), by(year)

This creates a variable that is the mean of age for each year. In addition to mean, there are min, max, sd, and several other statistics.

egen numobs = count(personid), by(personid year)

"Count" simply counts the number of observations within each year.  This can be used to make sure that you have the same number of observations for each respondent in each year.

egen city_yr = group(cityname year)

egen city_yr = group(cityname year), label

"Group" numbers the groups formed by crossing cityname and year. The groups are numbered consecutively which makes this a good variable to use in analysis. The "label" option causes Stata to use the value labels (if any) of cityname and year in creating city_yr.

egen comp_id=concat(householdid familyid personid),decode p(/)

The "concat" function is very useful when you have two or more variables that you want to combine to form one variable but adding or multiplying them would not make sense. The "decode" option works like the "decode" command in that it uses the value labels to create the new variable. The "p()" option allows you to put a separator character between the values.

destring d_income, gen(inc_pct_num) ignore("$")

destring inc_pct, gen(inc_pct_num) percent

destring inc_pct, gen(inc_pct_num) percent force

The "destring" command will convert a string variable into a numeric variable. It is used particularly when you have data that include special characters such as dollar or percent signs. The general form of the command is to specify the string variable, generate a new numeric variable, and the character or characters you want to remove.

If you have a percent variable with a percent sign, you can use the "percent" option. This has the same effect as specifying ignore("%") and then multiplying the result by 100.

Using the "force" option tells Stata that if it can't make a proper conversion, then the new variable should have a missing value.

gen numvar = real(str_num)

The "real" function simply tells Stata to convert all numbers in strvar into numeric data. Anything that is not a number will be made missing. Use the real function only when you do not have special characters.

encode city, gen(citynum)

Sometimes you have a legitimate string variable such as city names. To use this variable in a statistical analysis it must be numeric. The "encode" command will accomplish this. A nice feature of this is that the character values will be used to automatically create value labels for the new numeric variable.

decode citynum2, gen(cityname)

To convert a number into a string, you can use the "decode" command. One caveat to the decode command is that the numeric variable must have value labels assigned.

gen city_str2 = string(city_num)

If you have to many values to bother making labels for, you can still make the numeric to string conversion using the "string" function with the generate command.

gen datevar=date(str_date, "mdy")

gen datevar=date(string_date19, "md19y")

gen datevar=date(string_date00, "mdy", 2010)

Whenever you have a date that has been entered as a single string variable, you can use the "date" function with the gen command to convert it. The string form of the date must have some kind of delimiter separating the month, day and year. Generally, if it is obvious to you what the month day and year are, then Stata will be able to make the conversion. The "mdy" portion tells Stata the order of the month day and year in the string variable.

If you have only two digit years, and they are all in the same century, then you can specify that century before the "y".

If, on the other hand all of your dates are not in the same century, then you must specify what the latest year might be.

gen birthdate=mdy(b_month,b_day,b_year)

gen intvdate=mdy(i_month,i_day,1999)

Sometimes, dates are entered as separate variables for the month, day and year. The "mdy" function allows us to convert these to date variables.

todate strdate, gen(num_date) p(yymmdd)

The "todate" command is not part of official Stata, you must install it yourself. The todate command lets us convert dates that do not have any kind of delimiter. As you might guess, the "p(yymmdd)" tells Stata the pattern of digits in the variable. There are other options so you should install it and check the help file.

gen age_today= birthdate-d(17sep2002)

We can also enter dates directly with "d()".

gen yearvar=year(birthdate)

gen monthvar=month(birthdate)

gen dayvar=day(birthdate)

Stata also has functions to extract different parts of date from a date variable. There are a few others you may find useful (help dexfcns)

gen age_intv=(intvdate-birthdate)/365.25

Now that we have two date variables, we can determine how old each person was at the time of the interview.

gen calendardate=ym(year,month)

gen age_calendar=(calendardate-ym(b_year,b_month))/12

Often your data may only be in monthly intervals.  Remember, “12” in monthly data means 12 months after January 1, 1960.

Now we can also calculate age at any point in the calendar.

format birthdate %d

format calendardate %tmmcy

Stata provides many display formats for your convenience. The "%d" will make this value display as "09SEP2002". For monthly data, we can use the "%tmmcy" format.